Webmaster-Talk.com > Coding Talk > ASP Forum > How can I add file extension limitations?

Reply
How can I add file extension limitations?
Old 11-28-2007, 02:48 PM How can I add file extension limitations?
Super Talker

Posts: 115
Talkupation: chrisj is on a distinguished road
I have this upload script I'm using and I'd like to add some code that would allow me to decide what types of files extensions will be allowed to be uploaded.

Can you help me with this?
Thank you.

Code:
<%@ Language=VBScript %>
<%
option explicit
Response.Expires = -1
Server.ScriptTimeout = 600
%>
<!-- #include file="aspupload.asp" -->
<%

' ****************************************************
  Dim uploadsDirVar
  uploadsDirVar = "C:/Documents and Settings/TAinput/"
' ****************************************************
function OutputForm()
%>
    <form name="frmSend" method="POST" enctype="multipart/form-data" action="uploadTester.asp" onSubmit="return onSubmitForm();">
 <B>File names:</B><br>
    File 1: <input name="attach1" type="file" size=35><br>
    File 2: <input name="attach2" type="file" size=35><br>
    File 3: <input name="attach3" type="file" size=35><br>
    File 4: <input name="attach4" type="file" size=35><br>
    <br>
 <!-- These input elements are obviously optional and just included here for demonstration purposes -->
 <B>Additional fields (demo):</B><br>
 Enter a number: <input type="text" name="enter_a_number"><br>
    Checkbox values: <input type="checkbox" value="1" name="checkbox_values">-1 <input type="checkbox" value="2" name="checkbox_values">-2<br>
 <!-- End of additional elements -->
    <input style="margin-top:4" type=submit value="Upload">
    </form>
<%
end function
function TestEnvironment()
    Dim fso, fileName, testFile, streamTest
    TestEnvironment = ""
    Set fso = Server.CreateObject("Scripting.FileSystemObject")
    if not fso.FolderExists(uploadsDirVar) then
        TestEnvironment = "<B>Folder " & uploadsDirVar & " does not exist.</B><br>The value of your uploadsDirVar is incorrect. Open uploadTester.asp in an editor and change the value of uploadsDirVar to the pathname of a directory with write permissions."
        exit function
    end if
    fileName = uploadsDirVar & "\test.txt"
    on error resume next
    Set testFile = fso.CreateTextFile(fileName, true)
    If Err.Number<>0 then
        TestEnvironment = "<B>Folder " & uploadsDirVar & " does not have write permissions.</B><br>The value of your uploadsDirVar is incorrect. Open uploadTester.asp in an editor and change the value of uploadsDirVar to the pathname of a directory with write permissions."
        exit function
    end if
    Err.Clear
    testFile.Close
    fso.DeleteFile(fileName)
    If Err.Number<>0 then
        TestEnvironment = "<B>Folder " & uploadsDirVar & " does not have delete permissions</B>, although it does have write permissions.<br>Change the permissions for IUSR_<I>computername</I> on this folder."
        exit function
    end if
    Err.Clear
    Set streamTest = Server.CreateObject("ADODB.Stream")
    If Err.Number<>0 then
        TestEnvironment = "<B>The ADODB object <I>Stream</I> is not available in your server.</B><br>Check the Requirements page for information about upgrading your ADODB libraries."
        exit function
    end if
    Set streamTest = Nothing
end function
function SaveFiles
    Dim Upload, fileName, fileSize, ks, i, fileKey
    Set Upload = New FreeASPUpload
    Upload.MaxFileSize = 10000
    Upload.Save(uploadsDirVar)
 ' If something fails inside the script, but the exception is handled
 If Err.Number<>0 then Exit function
    SaveFiles = ""
    ks = Upload.UploadedFiles.keys
    if (UBound(ks) <> -1) then
        SaveFiles = "<B>Files uploaded:</B> "
        for each fileKey in Upload.UploadedFiles.keys
            SaveFiles = SaveFiles & Upload.UploadedFiles(fileKey).FileName & " (" & Upload.UploadedFiles(fileKey).Length & "B) "
        next
    else
        SaveFiles = "The file name specified in the upload form does not correspond to a valid file in the system."
    end if
 SaveFiles = SaveFiles & "<br>Enter a number = " & Upload.Form("enter_a_number") & "<br>"
 SaveFiles = SaveFiles & "Checkbox values = " & Upload.Form("checkbox_values") & "<br>"
end function
%>
 
<HTML>
<HEAD>
<Title>WTA</Title>
<style type="text/css">
body {margin: 1px 100px; 0px 100px;
padding: 1px;}
</style>
</HEAD>
<BODY leftMargin=0 topMargin=0 marginheight="0" marginwidth="0"  body {border-left: 1px solid #000; }>
<TABLE cellSpacing=0 valign=top cellPadding=0 width=100% border=0>
 <TR valign=middle height=10>
  <TD class=headera1><IMG src="/images/clear.gif" height=1 width=159 border=0></TD>
  <TD width="100%" align=right class=headera2>&nbsp;</TD>
 </TR>
 <TR>
   <TD class=headera3><IMG src="/images/clear.gif" height=1 width=159 border=0></TD>
  <TD width="100%" align=right class=headera4>&nbsp;</TD>
  </tr>
<TR valign=top>
  <TD><!--<IMG src="/smusermanager/images/logo1.gif" height=150 width=159 border=0>--></TD>
  <TD valign=left width=795 height=1><!--<font class=setuptext><IMG src="/smusermanager/images/clear.gif">--><IMG src="/images/topimg11.jpg">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;<IMG src="/images/topimg2.jpg"></font></TD>
 </TR>
 <TR valign=top height=1>
  <TD colspan=2 class=black><IMG src="/images/clear.gif" height=1 width=100% border=0></TD>
 </TR>
</TABLE>
</TD>
<TABLE cellSpacing=20 valign=top cellPadding=0 height=100% width=100% border=0>
 <TR valign=top>
  <TD width=10%>
   <TABLE cellSpacing=0 valign=top cellPadding=0 width=100% border=0>
    <TR valign=middle>
     <TD valign=middle class=lightgrey><IMG src="/images/clear.gif" height=20 width=160 align=absmiddle></TD>
    </TR>
    <TR valign=top height=2>
     <TD><IMG src="/images/clear.gif" height=2 width=160 border=0></TD>
    </TR>
    <!--<TR valign=top height=3>
     <TD class=gray><IMG src="/images/clear.gif" height=3 width=160 border=0></TD>
    </TR>-->
   </TABLE>

   <TABLE cellSpacing=0 cellPadding=0 width=100% border=0>
    <TR>
     <TD><font class=tbody>
     <!--<IMG src="/smusermanager/images/sepline130.gif"><br>
     <font class=smallheading><b>Navigation Menu</b></font><br>
     <IMG src="/smusermanager/images/sepline130.gif">-->

   <form action="/smusermanager/members/default.asp?action=login" method=post name=login language="JAVASCRIPT" onsubmit="return Validate();"><input type=hidden name=todo value="login"><input type=hidden name=url value="/smusermanager/members/default.asp">
<table border=0 cellspacing=0 cellpadding=0 width=95% align=center class=colorformborder><tr class=colorformborder><td><table border=0 cellspacing=0 width=100% cellpadding=0><tr class=colorformborder><td colspan=2><table border=0 cellspacing=1 cellpadding=5 width=100% colspan=2><tr class=colorformheader><td colspan=2><font class=textsize9><font color=white><b>Login Here</b></font></td></tr>
<tr class=colorformfields><td align=center colspan=2><font class=textsize9></font></td></tr><tr class=colorformfieldsalt><td align=right width=50% ><font class=textsize9>Email Address</font></td><td><font class=textsize9><input class=fieldbox type=text size=20 maxlength=50 name="members_username"></font></td></tr>
<tr class=colorformfields><td align=right width=20% ><font class=textsize9>Password</font></td><td><font class=textsize9><input class=fieldbox type=password size=20 maxlength=50 name="members_password"></font></td></tr><tr class=colorformfields><td colspan=2 align=right><font class=textsize9><input class=fieldbox type=submit value="Login" id=submit2 name=submit2></font></td></tr>
</td></tr></table></td></tr></table></td></tr></table></form>
<div style="padding-left: 24px;"> <font face="Arial" color="#000000" size="3"><img src="/images/Hphone.gif" style="vertical-align: middle;"> <a href="?action=login">&nbsp;&nbsp;Home</a><br><br>
      <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone1.gif">--><img src="/images/hphone1.gif" style="vertical-align: middle;"><a href="?action=register">&nbsp;&nbsp;Register</a><br><br>
      <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone2.gif">--><img src="/images/hphone2.gif" style="vertical-align: middle;"><a href="?action=forgotusername">&nbsp;&nbsp;FAQ</a><br><br>
      <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone3.gif">--><img src="/images/hphone3.gif" style="vertical-align: middle;"><a href="?action=forgotusername">&nbsp;&nbsp;Terms Of Use</a><br><br>
      <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone4.gif">--><img src="/images/hphone4.gif" hspace="4px" style="vertical-align: middle;">
<a href="?action=forgotusername">&nbsp;&nbsp;Contact Us</a><br><br>
                        <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone5.gif">--><img src="/images/hphone5.gif" style="vertical-align: middle;"><a href="?action=forgotpass">&nbsp;&nbsp;Forgot Password</a><br><br>
      <IMG src="/images/clear.gif" width=1 height=5><br><!--<IMG src="/images/hphone7.gif">--><img src="/images/hphone7.gif" style="vertical-align: middle;"><a href="?action=forgotusername">&nbsp;&nbsp;Forgot Username</a></font></div>
     <!--<IMG src="/smusermanager/images/clear.gif" width=1 height=5><br><IMG src="/smusermanager/images/link_arrow.gif"> <a href="?action=maillist">Newsletter</a>-->
     </font>
<!--<IMG src="/images/headphone.gif">-->
</TD>
    </TR>
   </TABLE>
  </TD>
  <TD width="1" height=100% background="/smusermanager/images/dot.gif">
   <TABLE cellSpacing=0 valign=top cellPadding=0 width=1 border=0>
    <TR valign=middle>
     <TD valign=middle class=lightgrey><IMG src="/smusermanager/images/clear.gif" height=20 width=1 align=absmiddle></TD>
    </TR>
    <TR valign=top height=2>
     <TD class=white><IMG src="/smusermanager/images/clear.gif" height=2 width=1 border=0></TD>
    </TR>
    <TR valign=top height=3>
     <TD class=gray><IMG src="/smusermanager/images/clear.gif" height=3 width=1 border=0></TD>
    </TR>
   </TABLE>

</TD>
  <TD width=100%  style="border-left: Solid #EE7600 3px;">
   <TABLE cellSpacing=0 cellPadding=0 width=100% border=0>
    <TR valign=middle>
     <TD valign=middle class=lightgrey><IMG src="/smusermanager/images/clear.gif" height=20 width=1 align=absmiddle></TD>
    </TR>
    <TR valign=top height=2>
     <TD class=white><IMG src="/smusermanager/images/clear.gif" height=2 width=1 border=0></TD>
    </TR>
    <TR valign=top height=3>
     <TD class=gray><IMG src="/smusermanager/images/clear.gif" height=3 width=11 border=0></TD>
    </TR>
    <TR>
     <TD valign=top><font class=tbody>
     <style>
.fieldbox
{
    BACKGROUND: #ffffff;
    BORDER-BOTTOM: #666666 1px solid;
    BORDER-LEFT: #666666 1px solid;
    BORDER-RIGHT: #666666 1px solid;
    BORDER-TOP: #666666 1px solid;
    COLOR: #333333;
    FONT-FAMILY: Verdana, Helvetica, Arial;
    FONT-SIZE: 13px
}
.colorwhite
{
    BACKGROUND-COLOR: white
}
.colorblack
{
    BACKGROUND-COLOR: black
}
.colortopbar
{
    BACKGROUND-COLOR: #999966
}
.colormenubar
{
    BACKGROUND-COLOR: #999966
}
.colormenufields
{
    BACKGROUND-COLOR: #cccc99
}
.colorformborder
{
    BACKGROUND-COLOR: #ffffff
}
.colorformheader
{
    BACKGROUND-COLOR: #A30100
}
.colorformfields
{
    BACKGROUND-COLOR: #ffffff
}
.colorformfieldsalt
{
    BACKGROUND-COLOR: #ffffff
}
.colorformresponse
{
    BACKGROUND-COLOR: white
}
.textsize16 A
{
    COLOR: navy;
    FONT-FAMILY: Verdana, Arial, helvetica;
    FONT-SIZE: 16pt;
    TEXT-DECORATION: none
}
.textsize16 A:active
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial, helvetica;
    FONT-SIZE: 16pt
}
.textsize16 A:hover
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial,
helvetica;
    FONT-SIZE: 16pt;
    TEXT-DECORATION: none
}
.textsize9
{
    COLOR: black;
    FONT-FAMILY: Verdana, Helvetica, Arial;
    FONT-SIZE: 9pt;
    LINE-HEIGHT: normal;
    TEXT-DECORATION: none
}
.textsize9 A
{
    COLOR: navy;
    FONT-FAMILY: Verdana, Arial, helvetica;
    FONT-SIZE: 19pt;
    TEXT-DECORATION: none
}
.textsize9 A:active
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial, helvetica;
    FONT-SIZE: 19pt
}
.textsize9 A:hover
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial,
helvetica;
    FONT-SIZE: 19pt;
    TEXT-DECORATION: none
}
.textsize8
{
    COLOR: black;
    FONT-FAMILY: Verdana, Helvetica, Arial;
    FONT-SIZE: 18pt;
    LINE-HEIGHT: normal;
    TEXT-DECORATION: none
}
.textsize8 A
{
    COLOR: navy;
    FONT-FAMILY: Verdana, Arial, helvetica;
    FONT-SIZE: 18pt;
    TEXT-DECORATION: none
}
.textsize8 A:active
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial, helvetica;
    FONT-SIZE: 18pt
}
.textsize8 A:hover
{
    COLOR: navy;
    FONT-FAMILY: verdana, arial,
helvetica;
    FONT-SIZE: 18pt;
    TEXT-DECORATION: none
}
.textsize16
{
    COLOR: red;
    FONT-FAMILY: Verdana, Helvetica, Arial;
    FONT-SIZE: 16pt;
    TEXT-DECORATION: none
}
.headera1 {BACKGROUND-COLOR: #A30100; border-bottom: 5px solid #FCB514; }
.headera2 {BACKGROUND-COLOR: #A30100; border-bottom: 5px solid #FCB514; }
.headera3 {BACKGROUND-COLOR: #ffffff; border-top: 1px solid #}
.headera4 {BACKGROUND-COLOR: #ffffff; border-top: 1px solid #}
.black {BACKGROUND-COLOR: white}
.white {BACKGROUND-COLOR: }
.lightgrey {BACKGROUND-COLOR: #ffffff}
.gray {BACKGROUND-COLOR: #ffffff}

.link {FONT-SIZE: 18pt;COLOR: ffffff;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.link A {COLOR: white;TEXT-DECORATION: none}
.link A:active {COLOR: white;TEXT-DECORATION: none}
.link A:hover {COLOR: white;TEXT-DECORATION: none}
.linksmall {FONT-SIZE: 18pt;COLOR: #99ccff;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.linksmall A {COLOR: #99ccff;TEXT-DECORATION: none}
.linksmall A:active {COLOR: #99ccff;TEXT-DECORATION: none}
.linksmall A:hover {COLOR: #3366ff;TEXT-DECORATION: none}
.pathlink {FONT-SIZE: 7.5pt;COLOR: #666666;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.pathlink A {COLOR: #666666;TEXT-DECORATION: none}
.pathlink A:active {COLOR: #666666;TEXT-DECORATION: none}
.pathlink A:hover {COLOR: #666666;TEXT-DECORATION: none}
.setuptext {FONT-SIZE: 24pt;COLOR: lightgrey;FONT-weight: bold;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.setuptextsmall {FONT-SIZE: 10pt;COLOR: lightgrey;FONT-weight: bold;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.heading {FONT-SIZE: 10pt;COLOR: #6384ad;FONT-weight: bold;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.smallheading {FONT-SIZE: 8pt;COLOR: #6384ad;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.tbody {FONT-SIZE: 12pt;COLOR: black;LINE-HEIGHT: 13pt;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.tbody A {COLOR: #000000;TEXT-DECORATION: none}
.tbody A:active {COLOR: #6384ad;TEXT-DECORATION: none}
.tbody A:hover {COLOR: #6384ad;TEXT-DECORATION: underline}
.textred {FONT-SIZE: 8pt;COLOR: #BD0000;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.textgreen {FONT-SIZE: 8pt;COLOR: #008000;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.textnavy {FONT-SIZE: 8pt;COLOR: #333399;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
.textgray {FONT-SIZE: 8pt;COLOR: gray;FONT-STYLE: italic;FONT-FAMILY: Verdana, sans-serif, Helvetica, Arial;}
/* START CSS */
#content {
    float: left;
    width: 596px;
    padding-left: 20px;
    background-color: #ffffff;
}
#column1 {
       float: left;
       padding: 0px;
       padding-right:0px
       padding-left: 0px;
       background-color: #ffffff;
       width: 270px;
}
#column2 {
       float: left;
       margin:0
       padding: 10px;
       padding-left: 20px;
       padding right: 0px
       background-color: #AAAAAA;
       width: 240px;
}

/* END CSS */
</style>
<SCRIPT LANGUAGE="JavaScript">errorcolor = '#eeeeee';</Script>
<table cellspacing=0 border=0 cellpadding=40 width=100% align=left>
 <tr>
  <td align=left valign=middle>
<script language="JAVASCRIPT">
 var errfound = false;
  function ValidLength(item, len) {
     return (item.length >= len);
  }
  function error(elem, text) {
     if (errfound) return;
     window.alert(text);
     elem.select();
     elem.focus();
     elem.style.backgroundColor=errorcolor;
     errfound = true;
  }
  function Validate() {
     errfound = false;
     d=document.login
     if (!ValidLength(d.members_username.value,1))error(d.members_username,"Username should not be blank.");
     if (!ValidLength(d.members_password.value,1))error(d.members_password,"Password should not be blank.");
     return !errfound;
  }
</script>
<TR valign=top>
<div style="border:0px solid #000000; width: 705px; padding-left: 75px; text-align:top;">

<style>
BODY {background-color: white;font-family:arial; font-size:12}
</style>
<script>
function onSubmitForm() {
    var formDOMObj = document.frmSend;
    if (formDOMObj.attach1.value == "" && formDOMObj.attach2.value == "" && formDOMObj.attach3.value == "" && formDOMObj.attach4.value == "" )
        alert("Please press the browse button and pick a file.")
    else
        return true;
    return false;
}
</script>
</HEAD>
<BODY>
<br><br>
<div style="border-bottom: #A91905 2px solid;font-size:16">Upload files to your server</div>
<%
Dim diagnostics
if Request.ServerVariables("REQUEST_METHOD") <> "POST" then
    diagnostics = TestEnvironment()
    if diagnostics<>"" then
        response.write "<div style=""margin-left:20; margin-top:30; margin-right:30; margin-bottom:30;"">"
        response.write diagnostics
        response.write "<p>After you correct this problem, reload the page."
        response.write "</div>"
    else
        response.write "<div style=""margin-left:150"">"
        OutputForm()
        response.write "</div>"
    end if
else
    response.write "<div style=""margin-left:150"">"
    OutputForm()
    response.write SaveFiles()
    response.write "<br><br></div>"
end if
%>
<br><br>
</p></div></tr></td></tr>
</table></TD></TR></TABLE>
  </TD>
  <!--<TD width="1" height=100% background="/smusermanager/images/dot.gif"><IMG src="/smusermanager/images/clear.gif" width="1" height=100% border=0></TD>-->
 </TR>
</TABLE>
<TABLE cellSpacing=0 valign=bottom cellPadding=0 width=100% border=0>
 <TR valign=top height=4>
  <TD colspan=2 class=gray><IMG src="/smusermanager/images/clear.gif" height=4 width=25 border=0></TD>
 </TR>
 <TR valign=middle height=25>
  <TD class=headera2>&nbsp;<FONT class=linksmall><font face="Arial" color="#ffffff" size="2">Copyright © 2007 <a href="" target="_blank">...</a>. All Rights Reserved.</FONT></TD>
  <TD align=right class=headera2><font class=linksmall><font face="Arial" color="#ffffff" size="2">Email : <A href="">removed</A> &nbsp;&nbsp;&nbsp; </font></TD>
 </TR>
</TABLE>
</Body>
</BODY>
</HTML>
Last edited by ForrestCroce : 06-20-2008 at 09:03 PM.
chrisj is offline
Reply With Quote
View Public Profile
 
When You Register, These Ads Go Away!
     
Old 11-28-2007, 03:23 PM Re: How can I add file extension limitations?
chrishirst's Avatar
Super Moderator

Posts: 11,495
Location: Blackpool. UK
Talkupation: chrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond repute
Now that's not quite as simple as the last modification
__________________
Chris. ->> Links are advertising NOT optimising!! <<-
Indifference will be the downfall of mankind, but who cares?
Code Samples | People Counting System
chrishirst is offline
Reply With Quote
View Public Profile Visit chrishirst's homepage!
 
Old 11-28-2007, 04:24 PM Re: How can I add file extension limitations?
chrishirst's Avatar
Super Moderator

Posts: 11,495
Location: Blackpool. UK
Talkupation: chrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond repute
Ok. Here we go

more variables (refer to http://www.webmaster-talk.com/asp-fo...file-size.html for anyone looking at this at a later date)

Code:
	private m_sFileError
	private m_bFileError
more new properties and a private method

Code:
	public property get Error()
		Error = m_bFileError
	end property
	
	public property get ErrorStatus()
		ErrorStatus = m_sFileError
	end property

	private function CheckExtension(strIn)
	' function to validate numeric input
		dim objRE
		set objRE = New RegExp
		objRE.Pattern = "^.+\.((jpg)|(jpeg)|(gif)|(bmp))$"
		objRE.Global = True
		CheckExtension = objRE.test(strIn)
		set objRE = nothing
	end function
And a brand new version of the Save method in the class

Code:
		Public Sub Save(path)
		Dim streamFile, fileItem

		if Right(path, 1) <> "\" then path = path & "\"

		if not uploadedYet then Upload

		For Each fileItem In UploadedFiles.Items
		m_bFileError = false 
		if fileItem.Length < m_lMaxFileSize then
			m_sFileError = "Exceeds maximum filesize"
			m_bFileError = true
		end if
		if not CheckExtension(fileItem.FileName)  then
			m_sFileError = "Invalid filetype"
			m_bFileError = true
		end if
		if not m_bFileError then 
			Set streamFile = Server.CreateObject("ADODB.Stream")
			streamFile.Type = 1
			streamFile.Open
			StreamRequest.Position=fileItem.Start
			StreamRequest.CopyTo streamFile, fileItem.Length
			streamFile.SaveToFile path & fileItem.FileName, 2
			streamFile.close
			Set streamFile = Nothing
			fileItem.Path = path & fileItem.FileName
		else
			fileItem.FileName = fileItem.FileName & " Discarded - " & m_sFileError
		end if
		 Next
	End Sub
The CheckExtension() needs a bit of explanation

This is a regular expression and check for the existence of a (.) followed by one of several extensions determined by the pattern.

"^.+\.((jpg)|(jpeg)|(gif)|(bmp))$"

above it checks for .jpg .jpeg .bmp and .gif If you need to add more, the way to add them is,

(ext)|

(the | is the pipe symbol ) which needs to go inside the first parenthesis before the existing (jpg)
__________________
Chris. ->> Links are advertising NOT optimising!! <<-
Indifference will be the downfall of mankind, but who cares?
Code Samples | People Counting System
chrishirst is offline
Reply With Quote
View Public Profile Visit chrishirst's homepage!
 
Old 11-28-2007, 05:31 PM Re: How can I add file extension limitations?
Super Talker

Posts: 115
Talkupation: chrisj is on a distinguished road
Thanks alot for your help and explanations.

Where, please, should I place the code you've posted here?

When it checks for the extensions, does it only allow the ones in the code?
If so, what happens when an extension not listed tries to upload?

Thanks again.
chrisj is offline
Reply With Quote
View Public Profile
 
Old 11-28-2007, 06:02 PM Re: How can I add file extension limitations?
chrishirst's Avatar
Super Moderator

Posts: 11,495
Location: Blackpool. UK
Talkupation: chrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond repute
The class file with my modifications and annotations
Code:
<%
'  For examples, documentation, and your own free copy, go to:
'  http://www.freeaspupload.net
'  Note: You can copy and use this script for free and you can make changes
'  to the code, but you cannot remove the above comment.

'Changes:
'Aug 2, 2005: Add support for checkboxes and other input elements with multiple values

' November 2007 added file size limitations and file extension checking

Class FreeASPUpload
	Public UploadedFiles
	Public FormElements

	Private VarArrayBinRequest
	Private StreamRequest
	Private uploadedYet
	
'	added by Chris Hirst www.candsdesign.co.uk November 2007 
	private m_lMaxFileSize
	private m_sByteMultiplier
	
	private m_sFileError
	private m_bFileError
' **********************************************
	Private Sub Class_Initialize()
		Set UploadedFiles = Server.CreateObject("Scripting.Dictionary")
		Set FormElements = Server.CreateObject("Scripting.Dictionary")
		Set StreamRequest = Server.CreateObject("ADODB.Stream")
		StreamRequest.Type = 1 'adTypeBinary
		StreamRequest.Open
		uploadedYet = false
'		m_lMaxFileSize = 10000
	End Sub
	
	Private Sub Class_Terminate()
		If IsObject(UploadedFiles) Then
			UploadedFiles.RemoveAll()
			Set UploadedFiles = Nothing
		End If
		If IsObject(FormElements) Then
			FormElements.RemoveAll()
			Set FormElements = Nothing
		End If
		StreamRequest.Close
		Set StreamRequest = Nothing
	End Sub
	
' ***************** new properties and methods 
'	added by Chris Hirst www.candsdesign.co.uk  November 2007 
	public function  setMaxFileSize(ByVal Val, Mult)
		m_sByteMultiplier = Mult
		select case lcase(m_sByteMultiplier)
			case ""
				m_lMaxFileSize = Val
			case "k"
				m_lMaxFileSize = Val * 1024
			case "m"
				m_lMaxFileSize = Val * (1024 * 1024)
		end select
	end function
	
	public property get MaxFileSize()
		MaxFileSize = m_lMaxFileSize
	end property
	
	public property get Error()
		Error = m_bFileError
	end property
	
	public property get ErrorStatus()
		ErrorStatus = m_sFileError
	end property

	private function CheckExtension(strIn)
	' function to validate numeric input
		dim objRE
		set objRE = New RegExp
		objRE.Pattern = "^.+\.((jpg)|(jpeg)|(gif)|(bmp))$"
		objRE.Global = True
		CheckExtension = objRE.test(strIn)
		set objRE = nothing
	end function

	public function getMult()
		select case lcase(m_sByteMultiplier)
			case ""
				getMult = "Bytes"
			case "k"
				getMult = "Kilobytes"
			case "m"
				getMult = "Megabytes"
		end select
	end function

' *************** end new property

	Public Property Get Form(sIndex)
		Form = ""
		If FormElements.Exists(LCase(sIndex)) Then Form = FormElements.Item(LCase(sIndex))
	End Property

	Public Property Get Files()
		Files = UploadedFiles.Items
	End Property

	'Calls Upload to extract the data from the binary request and then saves the uploaded files
	' Save method recoded November 2007 to add checks for files size and extensions 
	
	Public Sub Save(path)
		Dim streamFile, fileItem

		if Right(path, 1) <> "\" then path = path & "\"

		if not uploadedYet then Upload

		For Each fileItem In UploadedFiles.Items
		m_bFileError = false 
		if fileItem.Length > m_lMaxFileSize then
			m_sFileError = "Exceeds maximum filesize"
			m_bFileError = true
		end if
		if not CheckExtension(fileItem.FileName)  then
			m_sFileError = "Invalid filetype"
			m_bFileError = true
		end if
		if not m_bFileError then 
			Set streamFile = Server.CreateObject("ADODB.Stream")
			streamFile.Type = 1
			streamFile.Open
			StreamRequest.Position=fileItem.Start
			StreamRequest.CopyTo streamFile, fileItem.Length
			streamFile.SaveToFile path & fileItem.FileName, 2
			streamFile.close
			Set streamFile = Nothing
			fileItem.Path = path & fileItem.FileName
		else
			fileItem.FileName = fileItem.FileName & " Discarded - " & m_sFileError
		end if
		 Next
	End Sub

	Public Function SaveBinRequest(path) ' For debugging purposes
		StreamRequest.SaveToFile path & "\debugStream.bin", 2
	End Function

	Public Sub DumpData() 'only works if files are plain text
		Dim i, aKeys, f
		response.write "Form Items:<br>"
		aKeys = FormElements.Keys
		For i = 0 To FormElements.Count -1 ' Iterate the array
			response.write aKeys(i) & " = " & FormElements.Item(aKeys(i)) & "<BR>"
		Next
		response.write "Uploaded Files:<br>"
		For Each f In UploadedFiles.Items
			response.write "Name: " & f.FileName & "<br>"
			response.write "Type: " & f.ContentType & "<br>"
			response.write "Start: " & f.Start & "<br>"
			response.write "Size: " & f.Length & "<br>"
		 Next
   	End Sub

	Private Sub Upload()
		Dim nCurPos, nDataBoundPos, nLastSepPos
		Dim nPosFile, nPosBound
		Dim sFieldName, osPathSep, auxStr

		'RFC1867 Tokens
		Dim vDataSep
		Dim tNewLine, tDoubleQuotes, tTerm, tFilename, tName, tContentDisp, tContentType
		tNewLine = Byte2String(Chr(13))
		tDoubleQuotes = Byte2String(Chr(34))
		tTerm = Byte2String("--")
		tFilename = Byte2String("filename=""")
		tName = Byte2String("name=""")
		tContentDisp = Byte2String("Content-Disposition")
		tContentType = Byte2String("Content-Type:")

		uploadedYet = true

		on error resume next
		VarArrayBinRequest = Request.BinaryRead(Request.TotalBytes)
		if Err.Number <> 0 then 
			response.write "<br><br><B>System reported this error:</B><p>"
			response.write Err.Description & "<p>"
			response.write "The most likely cause for this error is the incorrect setup of AspMaxRequestEntityAllowed in IIS MetaBase. Please see instructions in the <A HREF='http://www.freeaspupload.net/freeaspupload/requirements.asp'>requirements page of freeaspupload.net</A>.<p>"
			Exit Sub
		end if
		on error goto 0 'reset error handling

		nCurPos = FindToken(tNewLine,1) 'Note: nCurPos is 1-based (and so is InstrB, MidB, etc)

		If nCurPos <= 1  Then Exit Sub
		 
		'vDataSep is a separator like -----------------------------21763138716045
		vDataSep = MidB(VarArrayBinRequest, 1, nCurPos-1)

		'Start of current separator
		nDataBoundPos = 1

		'Beginning of last line
		nLastSepPos = FindToken(vDataSep & tTerm, 1)

		Do Until nDataBoundPos = nLastSepPos
			
			nCurPos = SkipToken(tContentDisp, nDataBoundPos)
			nCurPos = SkipToken(tName, nCurPos)
			sFieldName = ExtractField(tDoubleQuotes, nCurPos)

			nPosFile = FindToken(tFilename, nCurPos)
			nPosBound = FindToken(vDataSep, nCurPos)
			
			If nPosFile <> 0 And  nPosFile < nPosBound Then
				Dim oUploadFile
				Set oUploadFile = New UploadedFile
				
				nCurPos = SkipToken(tFilename, nCurPos)
				auxStr = ExtractField(tDoubleQuotes, nCurPos)
                ' We are interested only in the name of the file, not the whole path
                ' Path separator is \ in windows, / in UNIX
                ' While IE seems to put the whole pathname in the stream, Mozilla seem to 
                ' only put the actual file name, so UNIX paths may be rare. But not impossible.
                osPathSep = "\"
                if InStr(auxStr, osPathSep) = 0 then osPathSep = "/"
				oUploadFile.FileName = Right(auxStr, Len(auxStr)-InStrRev(auxStr, osPathSep))

				if (Len(oUploadFile.FileName) > 0) then 'File field not left empty
					nCurPos = SkipToken(tContentType, nCurPos)
					
                    auxStr = ExtractField(tNewLine, nCurPos)
                    ' NN on UNIX puts things like this in the streaa:
                    '    ?? python py type=?? python application/x-python
					oUploadFile.ContentType = Right(auxStr, Len(auxStr)-InStrRev(auxStr, " "))
					nCurPos = FindToken(tNewLine, nCurPos) + 4 'skip empty line
					
					oUploadFile.Start = nCurPos-1
					oUploadFile.Length = FindToken(vDataSep, nCurPos) - 2 - nCurPos
					
					If oUploadFile.Length > 0 Then UploadedFiles.Add LCase(sFieldName), oUploadFile
				End If
			Else
				Dim nEndOfData
				nCurPos = FindToken(tNewLine, nCurPos) + 4 'skip empty line
				nEndOfData = FindToken(vDataSep, nCurPos) - 2
				If Not FormElements.Exists(LCase(sFieldName)) Then 
					FormElements.Add LCase(sFieldName), String2Byte(MidB(VarArrayBinRequest, nCurPos, nEndOfData-nCurPos))
				else
                    FormElements.Item(LCase(sFieldName))= FormElements.Item(LCase(sFieldName)) & ", " & String2Byte(MidB(VarArrayBinRequest, nCurPos, nEndOfData-nCurPos)) 
                end if 

			End If

			'Advance to next separator
			nDataBoundPos = FindToken(vDataSep, nCurPos)
		Loop
		StreamRequest.Write(VarArrayBinRequest)
	End Sub

	Private Function SkipToken(sToken, nStart)
		SkipToken = InstrB(nStart, VarArrayBinRequest, sToken)
		If SkipToken = 0 then
			Response.write "Error in parsing uploaded binary request."
			Response.End
		end if
		SkipToken = SkipToken + LenB(sToken)
	End Function

	Private Function FindToken(sToken, nStart)
		FindToken = InstrB(nStart, VarArrayBinRequest, sToken)
	End Function

	Private Function ExtractField(sToken, nStart)
		Dim nEnd
		nEnd = InstrB(nStart, VarArrayBinRequest, sToken)
		If nEnd = 0 then
			Response.write "Error in parsing uploaded binary request."
			Response.End
		end if
		ExtractField = String2Byte(MidB(VarArrayBinRequest, nStart, nEnd-nStart))
	End Function

	'String to byte string conversion
	Private Function Byte2String(sString)
		Dim i
		For i = 1 to Len(sString)
		   Byte2String = Byte2String & ChrB(AscB(Mid(sString,i,1)))
		Next
	End Function

	'Byte string to string conversion
	Private Function String2Byte(bsString)
		Dim i
		String2Byte =""
		For i = 1 to LenB(bsString)
		   String2Byte = String2Byte & Chr(AscB(MidB(bsString,i,1))) 
		Next
	End Function
End Class

Class UploadedFile
	Public ContentType
	Public Start
	Public Length
	Public Path
	Private nameOfFile

    ' Need to remove characters that are valid in UNIX, but not in Windows
    Public Property Let FileName(fN)
        nameOfFile = fN
        nameOfFile = SubstNoReg(nameOfFile, "\", "_")
        nameOfFile = SubstNoReg(nameOfFile, "/", "_")
        nameOfFile = SubstNoReg(nameOfFile, ":", "_")
        nameOfFile = SubstNoReg(nameOfFile, "*", "_")
        nameOfFile = SubstNoReg(nameOfFile, "?", "_")
        nameOfFile = SubstNoReg(nameOfFile, """", "_")
        nameOfFile = SubstNoReg(nameOfFile, "<", "_")
        nameOfFile = SubstNoReg(nameOfFile, ">", "_")
        nameOfFile = SubstNoReg(nameOfFile, "|", "_")
    End Property

    Public Property Get FileName()
        FileName = nameOfFile
    End Property

    'Public Property Get FileN()ame
End Class


' Does not depend on RegEx, which is not available on older VBScript
' Is not recursive, which means it will not run out of stack space
Function SubstNoReg(initialStr, oldStr, newStr)
    Dim currentPos, oldStrPos, skip
    If IsNull(initialStr) Or Len(initialStr) = 0 Then
        SubstNoReg = ""
    ElseIf IsNull(oldStr) Or Len(oldStr) = 0 Then
        SubstNoReg = initialStr
    Else
        If IsNull(newStr) Then newStr = ""
        currentPos = 1
        oldStrPos = 0
        SubstNoReg = ""
        skip = Len(oldStr)
        Do While currentPos <= Len(initialStr)
            oldStrPos = InStr(currentPos, initialStr, oldStr)
            If oldStrPos = 0 Then
                SubstNoReg = SubstNoReg & Mid(initialStr, currentPos, Len(initialStr) - currentPos + 1)
                currentPos = Len(initialStr) + 1
            Else
                SubstNoReg = SubstNoReg & Mid(initialStr, currentPos, oldStrPos - currentPos) & newStr
                currentPos = oldStrPos + skip
            End If
        Loop
    End If
End Function
%>
__________________
Chris. ->> Links are advertising NOT optimising!! <<-
Indifference will be the downfall of mankind, but who cares?
Code Samples | People Counting System
Last edited by chrishirst : 12-05-2007 at 05:37 AM. Reason: logic error corrected
chrishirst is offline
Reply With Quote
View Public Profile Visit chrishirst's homepage!
 
Old 11-28-2007, 06:22 PM Re: How can I add file extension limitations?
Super Talker

Posts: 115
Talkupation: chrisj is on a distinguished road
Thanks again vey much.
chrisj is offline
Reply With Quote
View Public Profile
 
Old 11-30-2007, 08:38 PM Re: How can I add file extension limitations?
chrishirst's Avatar
Super Moderator

Posts: 11,495
Location: Blackpool. UK
Talkupation: chrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond reputechrishirst has a reputation beyond repute
when doing some testing and updating I spotted a logic error

This line
Code:
if fileItem.Length < m_lMaxFileSize then
should be
Code:
if fileItem.Length > m_lMaxFileSize then
__________________
Chris. ->> Links are advertising NOT optimising!! <<-
Indifference will be the downfall of mankind, but who cares?
Code Samples | People Counting System
chrishirst is offline
Reply With Quote
View Public Profile Visit chrishirst's homepage!
 
Old 01-03-2008, 09:32 AM Re: How can I add file extension limitations?
Super Talker

Posts: 115
Talkupation: chrisj is on a distinguished road
Thanks again.
chrisj is offline
Reply With Quote
View Public Profile
 
Reply     « Reply to How can I add file extension limitations?
 
Previous Thread | Next Thread Webmaster-Talk.com > Coding Talk > ASP Forum > How can I add file extension limitations?

Thread Tools

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts
vB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Trackbacks are Off
Pingbacks are Off
Refbacks are Off


Webmaster Resources Marketplace:
Software Development Company | Webhosting.UK.com
Web Templates | Text Link Brokers | Stock Photos


   
RSS Feed  Feeds: RSS   JS   XML
RSS Feed  Feeds for this forum: RSS   JS   XML

 


Page generated in 0.14582 seconds with 13 queries