Hi

I'm having a bit of trouble with the script below. I use this to force MP3 files to download instead of open up in a browser. This works fine EXCEPT that it doesn't allow files over 4MB to download. Why is this? If I type the complete file name in the address bar of IE (i.e. "www.mysite.com/download/mysong.mp3"), it downloads fine. Any ideas?

Thanks

M

*****

<%@LANGUAGE="VBSCRIPT"%>
<%
Response.Buffer=true
On Error Resume Next
'Create a stream object
Dim tfm_downloadStream
Set tfm_downloadStream = Server.CreateObject("ADODB.Stream")
tfm_downloadStream.Type = 1
tfm_downloadStream.Open
tfm_downloadStream.LoadFromFile Server.Mappath(Request.Form("FileTitle"))
If Err.number = 0 Then
Response.Clear
Response.ContentType = "application/octet-stream"
Response.AddHeader "Content-Disposition", "attachment; filename=NewDownload.mp3"
Response.AddHeader "Content-Transfer-Encoding","binary"
Response.BinaryWrite tfm_downloadStream.Read
tfm_downloadStream.Close
Set tfm_downloadStream = Nothing
Response.End()
Else
tfm_downloadStream.Close
Set tfm_downloadStream = Nothing
Response.Redirect("error.asp")
End If
%>

What error are you getting? Please elaborate.

No error message. The file appears to download in less than a second but is zero kb in size. It looks like and MP3 but there's nothing in it! Only applies to files over 4MB. Under 4MB, the process works fine.

M

Hmmm...tuff one. I'll ask some people if they have any ideas.

Good luck!

Try here:
http://www.maximumasp.com/maxtrack.asp?kb=790

when downloading large files, even if we had response.buffer set to false this would be an issue since we are trying to send all the content to the client at one time

Response.BinaryWrite tfm_downloadStream.Read

.

however, what I did was, read the file in chunks just smaller than the maximum buffer size, this seems to work very efficiently for me:

 
<%
 do while not tfm_downloadStream.EOS
   '3670016 = 3.5 MB (the IIS limit is 4 MB)
  response.binaryWrite tfm_downloadStream.read(3670016) 
  response.flush
 loop
%>

Please let me know if this helps or if there is any reason this should not be done.

Hi yea,
I have files that are nearly 15 meg in size. regarding "the IIS limit is 4 MB"


<%
do while not tfm_downloadStream.EOS
'3670016 = 3.5 MB (the IIS limit is 4 MB)
response.binaryWrite tfm_downloadStream.read(3670016)
response.flush
loop
%>

Can you advise at all


cheers

spud

Originally Posted by twocans

Hi yea,
I have files that are nearly 15 meg in size. regarding "the IIS limit is 4 MB"


<%
do while not tfm_downloadStream.EOS
'3670016 = 3.5 MB (the IIS limit is 4 MB)
response.binaryWrite tfm_downloadStream.read(3670016)
response.flush
loop
%>

Now this an interesting approach; I never thought of buffering a file download like this. Nice workaround.

The issue here is that a Windows server will only push upto 4 MB in a response; if the data in the response is over 4 MB, the server won't be able to push the whole response. However, that is just a default setting in the IIS Metabase. Another way to deal with this is to go into the IIS Metabase and change the allocation allowed on the site for a response to whatever your upper bound is.

Frankly, I like the response buffering approach better; I'll have to try that at my next opportunity.